代码拉取完成,页面将自动刷新
同步操作将从 初雨团队/VC-LTL 强制同步,此操作会覆盖自 Fork 仓库以来所做的任何修改,且无法恢复!!!
确定后同步将在后台操作,完成时将刷新页面,请耐心等待。
@echo off
::
:: VC-LTL自动化加载配置,建议你将此文件单独复制到你的工程再使用,该文件能自动识别当前环境是否存在VC-LTL,并且自动应用。
::
:: 使用方法:
:: 1. 启动 vcvars32.bat/vcvars64.bat 然后执行此脚本,运行完成后将自动修改include以及lib环境变量,方便nmake以及纯cl用户引用VC-LTL。
:: 2. 务必保证所有依赖的静态库也均用VC-LTL重新编译。
::
:: VC-LTL默认搜索顺序
:: 1. “VC-LTL helper for nmake.cmd”所在根目录,即 %~dp0
:: 2. “VC-LTL helper for nmake.cmd”所在根目录下的VC-LTL目录,即 %~dp0VC-LTL
:: 3. “VC-LTL helper for nmake.cmd”所在父目录,即 %~dp0..
:: 3. “VC-LTL helper for nmake.cmd”所在父目录下的VC-LTL目录,即 %~dp0..\VC-LTL
:: 4. 当前目录,即 %cd%
:: 5. 当前目录下的VC-LTL目录,即 %cd%\VC-LTL
:: 6. 当前目录的父目录下的VC-LTL目录,即 %cd%\..\VC-LTL
:: 7. 注册表HKEY_CURRENT_USER\Code\VC-LTL@Root
::
:: 把VC-LTL放在其中一个位置即可,VC-LTL就能被自动引用。
::
:: 如果你对默认搜索顺序不满,你可以修改此文件。你也可以直接指定%VC_LTL_Root%环境变量更加任性的去加载VC-LTL。
::
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::VC-LTL设置::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::取消下方注释可以开启VC-LTL轻量模式,轻量模式更加注重体积控制,但是CRT规范将会维持在VS2008。如果你需要高度兼容微软UCRT,那么请不要打开此选项!!!
::set DisableAdvancedSupport=true
::取消下方注释可以开启强制XP兼容模式,默认情况下仅在选择WinXP工具集时才开启。
::set SupportWinXP=true
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
if "%VC_LTL_Root%" NEQ "" goto LoadConfig
::搜索VC-LTL目录
::脚本文件根目录存在VC-LTL?
if exist "%~dp0_msvcrt.h" set VC_LTL_Root=%~dp0&& goto LoadConfig
::脚本文件根目录下存在VC-LTL?
if exist "%~dp0VC-LTL\_msvcrt.h" set VC_LTL_Root=%~dp0VC-LTL&& goto LoadConfig
::脚本文件父目录存在VC-LTL?
if exist "%~dp0..\_msvcrt.h" set VC_LTL_Root=%~dp0..&& goto LoadConfig
::脚本文件父目录存在VC-LTL?
if exist "%~dp0..\VC-LTL\_msvcrt.h" set VC_LTL_Root=%~dp0..\VC-LTL&& goto LoadConfig
::当前根目录就是VC-LTL?
if exist "%cd%\_msvcrt.h" set VC_LTL_Root=%cd%&& goto LoadConfig
::当前根目录存在VC-LTL?
if exist "%cd%\VC-LTL\_msvcrt.h" set VC_LTL_Root=%cd%\VC-LTL&& goto LoadConfig
::当前父目录存在VC-LTL?
if exist "%cd%\..\VC-LTL\_msvcrt.h" set VC_LTL_Root=%cd%\..\VC-LTL&& goto LoadConfig
::读取注册表 HKCU\Code\VC-LTL@Root
for /f "tokens=1,2*" %%i in ('reg query "HKCU\Code\VC-LTL" /v Root ') do set VC_LTL_Root=%%k
if "%VC_LTL_Root%" == "" goto:eof
:LoadConfig
call "%VC_LTL_Root%\config\config.cmd"
此处可能存在不合适展示的内容,页面不予展示。您可通过相关编辑功能自查并修改。
如您确认内容无涉及 不当用语 / 纯广告导流 / 暴力 / 低俗色情 / 侵权 / 盗版 / 虚假 / 无价值内容或违法国家有关法律法规的内容,可点击提交进行申诉,我们将尽快为您处理。