// Top-level build file where you can add configuration options common to all sub-projects/modules.
buildscript {
    repositories {
        jcenter()
        maven { url 'https://jitpack.io' }
        google()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:4.0.2'
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.8.5'
        classpath 'com.github.dcendents:android-maven-gradle-plugin:2.1'
    }
}

plugins {
    id "com.diffplug.gradle.spotless" version "3.25.0"
}

allprojects {
    repositories {
        jcenter()
        maven { url 'https://jitpack.io' }
        google()
    }
}

subprojects {
    if (it.name != 'app') {
        apply plugin: 'com.diffplug.gradle.spotless'
        spotless {
            java {
                target fileTree('.') {
                    include '**/*.java'
                }
                googleJavaFormat('1.7').aosp()
                licenseHeaderFile project.rootProject.file('spotless/copyright.java')
            }
        }
    } else {
        apply plugin: 'com.diffplug.gradle.spotless'
        spotless {
            java {
                target '**/*.java'
                googleJavaFormat('1.7').aosp()
            }
        }
    }
}

ext {
    android = [
            compileSdkVersion: 29,
            buildToolsVersion: "29.0.3",
            minSdkVersion    : 14,
            targetSdkVersion : 29,
            versionCode      : 14,
            versionName      : "0.2.0"
    ]
    bintray = [
            siteUrl       : 'https://github.com/dkzwm/FormatEditText',
            gitUrl        : 'https://github.com/dkzwm/FormatEditText.git',
            groupId       : "me.dkzwm.widget.fet",
            libVersion    : android.versionName,
            developerId   : "dkzwm",
            developerName : "Zhang Weiming",
            developerEmail: "aidkzwm@gmail.com",
            licenseName   : "MIT License",
            licenseUrl    : "https://opensource.org/licenses/MIT",
    ]
    allLicenses = ['MIT']
}